Урок №13 Ваш первый советник (часть 1)

Уроки

                 Добро пожаловать на очередной курс MQL4! В предыдущих уроках мы создали наш первый индикатор. Хоть он и не был полезен нам как трейдерам, он был весьма полезен нам как программистам.

                Индикаторы, в общем, очень важны для технического анализа рынков и попыток предсказания будущее движение цены. Но для того, чтобы использовать индикаторы необходимо сидеть перед монитором с широко открытыми глазами и вручную совершать сделки.

                  Если Вы вдруг устанете, решите выпить чашечку чая или взять небольшой отпуск, то Вам придётся рассмотреть одну из следующих опций:

  1. Можно кого-нибудь нанять, чтобы он следил за терминалом и звонил Вам каждые 5 минут, чтобы рассказать, что происходит. Если этот человек профессионал, то Вы будете тратить на него всю свою прибыль. А если он новичок, то Вы потратите на него весь свой капитал.
  2. Вторая опция – автоматизировать свою торговлю. Именно для этого нужны советники — они же торговые эксперты — они же  механические торговые системы (МТС).

                  Советник – это программа, написанная на MQL4 (ведь мы изучаем MQL4, верно?), которая использует Ваши любимые индикаторы и торговые системы для автоматизации Ваших торгов. Он покупает, продаёт и модифицирует ордера за Вас.

                Сегодня мы создадим нашего первого торгового советника. Начнём! Для этого предпримем два шага:

Шаг 1

                 Если Вы ещё не открыли свой MetaEditor, то пора бы это сделать. Затем выберите Файл->Создать (или просто нажмите CTRL+N). Появится помощник (как при создании первого индикатора). На этот раз надо выбрать пункт “Советник”.

 

post-798

Рис. 1 – Помощник. 1-й шаг

Шаг 2

                После нажатия кнопки “Next”, Вы окажетесь в окошке общих параметров советника. Помощник позволяет Вам назначить свойства Вашего эксперта и задать внешние переменные, которые будут использоваться в нём. На этом шаге можно задать следующие свойства:

  • Имя. Название Вашего советника. Мы назовём его My_first_EA.
  • Автор. Имя автора. Введите своё имя.
  • Ссылка. Ссылка на Ваш сайт или e-mail.
  • Параметры. Это список внешних (extern) параметров. Это те параметры, которые пользователь сможет менять из окошка настроек советника. Для добавления нового параметра нажмите кнопку “Добавить”. Нажатие этой кнопки приведёт к появлению новой записи в списке внешних переменных.

                   Каждая переменная имеет три поля:

  1. Имя: двойной щелчок по этому полю позволит Вам задать имя (идентификатор) переменной.
  2. Тип: двойной щелчок по этому полю позволит Вам задать тип переменной.
  3. Начальное значение: двойной щелчок по этому полю позволит Вам задать начальное значение переменной. Последнее поле является опциональным, что означает, что его можно оставить пустым.

В нашем случае, мы добавим три переменные:

post-798-04

 

Рис. 2 – Помощник. 2-й шаг

               Теперь нажмите кнопку “Finish”. MetaEditor перенесёт Вас к коду, подготовленному помощником и сохранит его в файл My_first_EA.mq4 в папке MetaTrader4\experts.\

              Замечание: торговых советников надо класть в папку MetaTrader4\experts, а индикаторы – в папку MetaTrader4\experts\indicators, иначе они не будут работать.

Помощник подготовил следующий код:

//+------------------------------------------------------------------+
//|												  My_First_EA.mq4 |
//|														   Kirill |
//|										  StockProgrammer@mail.ru |
//+------------------------------------------------------------------+
#property copyright "Kirill"
#property link	  "StockProgrammer@mail.ru"

//---- input parameters
extern double	TakeProfit=350.0;
extern double	Lots=0.1;
extern double	TrailingStop=35.0;
//+------------------------------------------------------------------+
//| expert initialization function								   |
//+------------------------------------------------------------------+
int init()
  {
//----

//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function								 |
//+------------------------------------------------------------------+
int deinit()
  {
//----

//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert start function											|
//+------------------------------------------------------------------+
int start()
  {
//----

//----
   return(0);
  }
//+------------------------------------------------------------------+

Теперь добавим свой код:

//+------------------------------------------------------------------+
//|												  My_First_EA.mq4 |
//|														   Kirill |
//|										  StockProgrammer@mail.ru |
//+------------------------------------------------------------------+
#property copyright "Kirill"
#property link	  "StockProgrammer@mail.ru"

//---- input parameters
extern double	TakeProfit=350.0;
extern double	Lots=0.1;
extern double	TrailingStop=35.0;
//+------------------------------------------------------------------+
//| expert initialization function								   |
//+------------------------------------------------------------------+
int init()
  {
//----

//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function								 |
//+------------------------------------------------------------------+
int deinit()
  {
//----

//----
   return(0);
  }

int Crossed (double line1 , double line2)
{
   static int last_direction = 0;
   static int current_direction = 0;
   static bool initial=true;

   if(line1>line2)current_direction = 1; //up
   if(line1<line2)current_direction = 2; //down

   if(current_direction != last_direction) //changed
   {
	  last_direction = current_direction;
     if(initial == false)
        return(current_direction);
     else
     	  initial = false;
   }

   else
   {
	  return (0);
   }

}

//+------------------------------------------------------------------+
//| expert start function                                            |
//+------------------------------------------------------------------+

int start()
{
//----
   int cnt, ticket, total;
   double shortEma, longEma;

   if(Bars<100)
   {
      Print("bars less than 100");
      return(0);
   }

   if(TakeProfit<10)
   {
      Print("TakeProfit less than 10");
      return(0); // check TakeProfit
   }

   shortEma = iMA(NULL,0,8,0,MODE_EMA,PRICE_CLOSE,0);
   longEma = iMA(NULL,0,13,0,MODE_EMA,PRICE_CLOSE,0);

   int isCrossed = Crossed (shortEma,longEma);

   total = OrdersTotal();
   for(cnt=0;cnt<total;cnt++)
   {
      OrderSelect(cnt, SELECT_BY_POS, MODE_TRADES);
      if(OrderType()<=OP_SELL && OrderSymbol()==Symbol())
      {
         if(OrderType()==OP_BUY) // long position is opened
         {
         // should it be closed?
            if(isCrossed == 2)
            {
               OrderClose(OrderTicket(),OrderLots(),Bid,3,Violet);   // close position
            }

         // check for trailing stop
            else if(TrailingStop>0)
            {
               if(Bid-OrderOpenPrice()>Point*TrailingStop)
               {
                  if(OrderStopLoss()<Bid-Point*TrailingStop)
                  {
                     OrderModify(OrderTicket(),OrderOpenPrice(),Bid-Point*TrailingStop,OrderTakeProfit(),0,Green);
                  }
               }
            }
         }

         else // go to short position
         {
         // should it be closed?
            if(isCrossed == 1)
            {
               OrderClose(OrderTicket(),OrderLots(),Ask,3,Violet);   // close position
            }

         // check for trailing stop
            else if(TrailingStop>0)
            {
               if((OrderOpenPrice()-Ask)>(Point*TrailingStop))
               {
                  if((OrderStopLoss()>(Ask+Point*TrailingStop)) || (OrderStopLoss()==0))
                  {
                     OrderModify(OrderTicket(),OrderOpenPrice(),Ask+Point*TrailingStop,OrderTakeProfit(),0,Red);
                  }
               }
            }
         }
      }
   }

   total = OrdersTotal();
   if(total < 1)
   {
      if(isCrossed == 1)
      {
         ticket=OrderSend(Symbol(),OP_BUY,Lots,Ask,3,0,Ask+TakeProfit*Point, "My EA",12345,0,Green);
         if(ticket>0)
         {
            if(OrderSelect(ticket,SELECT_BY_TICKET,MODE_TRADES))
               Print("BUY order opened : ",OrderOpenPrice());
         }
         else Print("Error opening BUY order : ",GetLastError());
            return(0);
      }

      if(isCrossed == 2)
      {
         ticket=OrderSend(Symbol(),OP_SELL,Lots,Bid,3,0,
         Bid-TakeProfit*Point,"My EA",12345,0,Red);
         if(ticket>0)
         {
            if(OrderSelect(ticket,SELECT_BY_TICKET,MODE_TRADES))
               Print("SELL order opened : ",OrderOpenPrice());
         }
         else Print("Error opening SELL order : ",GetLastError());
            return(0);

      }
   }   

   return(0);
}

//+------------------------------------------------------------------+

                 Можно скопировать код прямо отсюда. Скомпилируйте эксперта, например, нажав F5. Напуганы?:) Не бойтесь этих 170 строчек кода, что Вы видите выше. Скоро мы их разберём строчка-за-строчкой. Это очень просто.

Протестируйте МТС:

                Прежде, чем разбирать код, проверим прибыльна ли созданная МТС. Замечание: эта МТС предназначена для работы с EUR/USD на ТФ H4.

Протестировать эксперта можно двумя способами:

Online-торговля

              При online-торговле результаты теста точнее, но надо потратить дни или даже месяцы, чтобы выяснить прибыльна или нет данная МТС. Для начала, необходимо разрешить советнику автоматизировать Вашу торговлю. В MetaTrader4 выберите Сервис -> Настройки (или просто нажмите CTRL+O). Во вкладке Советники разрешите следующие опции: Включить советники. Разрешить советнику торговать. И нажмите кнопку “OK”.

 

post-798-0533

Рис.3 – Разрешаем автоторговлю.

                   Теперь найдите своего эксперта в  Навигаторе  в разделе Советники и перетащите его на график EUR/USD H4.

post-798-070304

 

Рис.4 – Советник включён.

Тестер стратегий

                 Второй метод тестирования МТС – это тестер стратегий. Он менее аккуратен, но зато занимает намного меньше времени. Об этом методе мы подробно поговорим позже. Сейчас просто вызовем его окошко, нажав F6.

Выберете параметры как на рисунке:

post-798-0781733

 

Рис.5 – Настройки тестера.

                Нажмите кнопку Старт. Далее Вас интересует вкладка отчёт. Далее постараемся вникнуть! Вот и сейчас наше практическое занятие подошло к завершению. В следующей части мы продолжим рассматривать урок по созданию нашего первого советника. Надеюсь было интересно!

Добавить комментарий